store/[org.clojure/clojure "1.8.0"] clj::clojure.core/import

Official Documentation

Add notes
Arities
==================================================
   [& import-symbols-or-lists]

Docstring
==================================================
  import-list => (package-symbol class-name-symbols*)

  For each name in class-name-symbols, adds a mapping from name to the
  class named by package.name to the current namespace. Use :import in the ns
  macro in preference to calling this directly.

Source

(defmacro import 
  "import-list => (package-symbol class-name-symbols*)

  For each name in class-name-symbols, adds a mapping from name to the
  class named by package.name to the current namespace. Use :import in the ns
  macro in preference to calling this directly."
  {:added "1.0"}
  [& import-symbols-or-lists]
  (let [specs (map #(if (and (seq? %) (= 'quote (first %))) (second %) %) 
                   import-symbols-or-lists)]
    `(do ~@(map #(list 'clojure.core/import* %)
                (reduce1 (fn [v spec] 
                          (if (symbol? spec)
                            (conj v (name spec))
                            (let [p (first spec) cs (rest spec)]
                              (into1 v (map #(str p "." %) cs)))))
                        [] specs)))))

Example 1

Edit
;; importing multiple classes in a namespace
(ns foo.bar
  (:import (java.util Date
                      Calendar)
           (java.util.logging Logger
                              Level)))

Example 2

Edit
;; Multiple imports at once.
(import '(java.util Date Calendar)
        '(java.net URI ServerSocket)
        java.sql.DriverManager)

Example 3

Edit
(import java.util.Date)
;; => java.util.Date

(def *now* (Date.))
;; => #'user/*now*

(str *now*)
;; => "Tue Jul 13 17:53:54 IST 2010"

Uses on crossclj